ORG 0000H

START: AJMP MAIN

TAB1: DB 128,64,32,16 ;Dn值表格

TAB2: DB 0C0H,92H,0C0H,0C0H ;數(shù)字0.5.0.0字段代碼表

TAB3: DB 0B0H,99H,82H,90H ;數(shù)字3.4.6.9字段代碼表

MAIN: MOV SCON,#0 ;設(shè)串行口模式0

SETB P3.7 ;接繼電器實(shí)現(xiàn)極性狀態(tài)改變，開始置P3.7=1

SETB P3.4 ;電壓及顯示控制按鈕

SETB P3.5 ;極性轉(zhuǎn)換按鈕

BEGIN: MOV SP, #60H

MOV 23H,#0 ;送輸出P1.7=1的Dn值指針

MOV 20H,#0 ;小數(shù)點(diǎn)一位指針指向“0”字符(20H是小數(shù)點(diǎn)的指針)

MOV 21H,#0 ;個(gè)位指針指向“3”字符(21H是個(gè)位數(shù)點(diǎn)的指針)

ACALL DSP ;調(diào)用顯示、輸出子程序

NOP

JNB P3.4,$

ACALL DEL200

;

KEY1: JB P3.4, KEY2 ;電壓及顯示鍵是否有鍵?

ACALL DEL10

JB P3.4, KEY2

ACALL K1

;

KEY2: JB P3.5, KEY1 ;極性轉(zhuǎn)換鍵是否有鍵?

ACALL DEL10

JB P3.5, KEY1

ACALL K2

AJMP KEY1

;

DEL10: MOV R6,#0DH ;10ms延時(shí)子程序

D1MS1: MOV R7,#0FFH

DLL1: DJNZ R7, DLL1

DJNZ R6, D1MS1

RET

;

DEL200: MOV R3, #0FFH ;200ms延時(shí)子程序

D1MS2: MOV R4, #0FFH

DLL2: DJNZ R4, DLL2

DJNZ R3, D1MS2

RET

;

K1: MOV A,23H ;電壓及顯示鍵處理子程序

CJNE A, #03H, REL1

AJMP BEGIN

REL1: INC 23H

INC 20H

INC 21H

ACALL DSP

NOP

JNB P3.4,$

ACALL DEL200

NOP

RET

;

K2: CPL P3.7 ;極性轉(zhuǎn)換鍵處理子程序

JNB P3.5,$

ACALL DEL200

NOP

RET

;

DSP: MOV R7, #02 ;顯示、輸出子程序

MOV R0, #20H

MOV R1, #21H

MOV DPTR, #TAB2

MOV A, @R0

DSP1: MOVC A, @A+DPTR

MOV SBUF, A

DSP2: JNB TI, DSP2

CLR TI

MOV A, @R1

MOV DPTR, #TAB3

DJNZ R7, DSP1

MOV DPTR, #TAB1

MOV A, 23H

MOVC A, @A+DPTR

MOV P1, A

RET

;

END

程序中定義了三個(gè)表TAB1、TAB2、TAB3，分別存放P1口的數(shù)據(jù)、小數(shù)點(diǎn)后一位字符、個(gè)位字符。并且用23H、20H、21H分別作為P1口的數(shù)據(jù)、小數(shù)點(diǎn)后一位字符、個(gè)位字符的指針，指針開始時(shí)均指向“0”，即分別對應(yīng)著128、0C0H、0B0H。

程序運(yùn)行后，調(diào)用“顯示/輸出子程序”，在“顯示/輸出子程序”中依次執(zhí)行：將字符“0”對應(yīng)的代碼“0C0H”發(fā)送、將字符“3”對應(yīng)的代碼“0B0H”發(fā)送、將P1口置為“128”（即表示P1.7—P1.0為10000000）。顯然在“顯示/輸出子程序”中輸出字符和置P1口的數(shù)據(jù)等，用的是查表指令MOVC A,@A+DPTR，DPTR是數(shù)據(jù)指針，查表時(shí)采用DPTR作為基址寄存器，在該指令執(zhí)行前，DPTR中存放表的起始地址（例如MOV DPTR,#TAB2），A的內(nèi)容（用MOV R0,#20H和MOV A,@R0兩條指令完成）作為無符號數(shù)與DPTR的內(nèi)容相加得到一個(gè)16位地址，由該地址指出的程序存儲器的單元的內(nèi)容送到累加器A中，再由MOV SBUF,A指令將字符對應(yīng)的代碼發(fā)送出去，同樣對P1口數(shù)據(jù)的傳送用指令MOV A,23H和MOVC A,@A+DPTR以及MOV P1,A完成。

程序在結(jié)束此次調(diào)用“顯示/輸出子程序”后，就反復(fù)掃描P3.4口和P3.5口，隨時(shí)響應(yīng)按鍵S1和S2的操作，如S1按下，則進(jìn)入“S1處理子程序”，即“電壓及顯示鍵處理子程序”；如S2按下，則進(jìn)入“S2處理子程序”即“極性轉(zhuǎn)換鍵處理子程序”。

在“電壓及顯示鍵處理子程序”中，每執(zhí)行一次該子程序，都是先將三個(gè)指針23H、20H、21H加1，然后調(diào)用“顯示/輸出子程序”，下面的過程是與開始一樣的，只不過，由于指針改變而改變了相應(yīng)代碼，實(shí)現(xiàn)顯示、穩(wěn)壓輸出為“4.5、4.5V”→“6.0、6.0V” →“9.0、9.0V”→“3.0、3.0V”的循環(huán)過程。注意，當(dāng)23H指針加到03H后，表明電路應(yīng)回到起始狀態(tài)，重新以“3.0、3.0V”開始，程序用CJNE A,#03H,ACTION1指令來控制，即當(dāng)A中內(nèi)容等于03H后，程序不會執(zhí)行標(biāo)號ACTION1開始的程序段，而是轉(zhuǎn)到執(zhí)行標(biāo)號FW的程序段，回到起始狀態(tài)。

在“極性轉(zhuǎn)換鍵處理子程序”中，每執(zhí)行一次該子程序，就對P3.7取反一次，實(shí)現(xiàn)極性轉(zhuǎn)換。